Cragne Manor room DAN5: Padded cell (Marius Müller)

This file is part of the Cragne Manor source code collection. Posted with the author's permission. All rights reserved.


"DAN5" by Marius Müller
 
Chapter 1 - Do Not Change Any Of This
 
Include Cragne Suite by Ryan Veeder.
 
[Don't mess with other people's rooms!]
 
DAN is a region.
 
DAN5 is a room in DAN. DAN4 is a room.
 
[Here is how I defined the door with DAN4 on my end. Hope that's okay.]
 
The door16 is a closed scenery door. The door16 is north of DAN4 and south of DAN5.
 
Rule for printing the name of door16 when the location is DAN5: say "padded door". Understand "door" and "padded" as door16.
 
Instead of examining door16 when the location is DAN5, say "It's a thick, padded door."
 
Part 1 - DAN5 Padded Cell
 
Instead of examining the player when the location is DAN5:
say “You look about as you'd expect after everything that happened to you in all the other rooms."
 
Printed name of DAN5 is "Padded cell (Marius Müller)".
 
Description of DAN5 is "The overhead lightbulb in its wire-mesh cage barely lights the room. Everything here seems a colorless beige - the cracked floor tiles, the thick cloth padding on the walls. A metal door leads south."
 
Tale-tiles are scenery in DAN5. The description is "The uneven floor tiles are cracked and smeared with dirt. In your mind, you compare them to other floors you've seen in the Manor." Understand "tiles" and "floor" as the tale-tiles.
 
tale-padding is scenery in DAN5. The description is "Thick cloth padding covers the floors and ceiling, fastened by deep-set buttons. One of them catches your eye. Where all the others are cloth-covered, this one is brass." Understand "padding" and "cloth" and "wall" as the tale-padding. The printed name is "padding".
 
 
 
[There is a secret button that opens a hidden compartment containing a) a way out b) a trophy for the Venus puzzle]
 
After examining the tale-padding for the first time:
    now the tale-button is in DAN5.
 
The tale-button is a thing. The printed name is "brass button". The initial appearance is "You've noticed a strange brass button among those that fix the padding to the wall." It is fixed in place. Understand "brass" and "button" as the tale-button. The description is "It's a brass button that, on closer inspections, looks more like a knob." Understand "knob" as the tale-button.
 
Check turning the tale-button for the first time:
    say "You turn the brass button and this whole section of the padded wall swings open, revealing a small secret compartment. A dusty trophy tumbles out of it and to the floor.";
    now the tale-switch is in DAN5;
    now the tale-trophy is in DAN5;
    remove the tale-button from play;
    stop the action.
 
The tale-straitjacket is wearable. Understand "straitjacket" as the tale-straitjacket. Understand "strait jacket"and "jacket" and "straightjacket" and "straight jacket" and "straps" and "Buckles" as the tale-straitjacket. The printed name of the tale-straitjacket is "strait jacket."
 
The description of the tale-straitjacket is "It's a canvas strait jacket, the kind used to immobilize violent or spastic mental patients. It fastens up the back with a complex series of buckles and straps, while the sleeves cross the chest and fasten around back, making it quite impossible to escape."
 
[Certain behavior is forbidden when wearing the straitjacket]
 
Instead of taking off the tale-straitjacket:
    say "You wiggle and twist, but to no avail.".
 
Looking is tale-behavior.
Jumping is tale-behavior.
Taking inventory is tale-behavior.
entering is tale-behavior.
exiting is tale-behavior.
getting off is tale-behavior.
Taking off is tale-behavior.
Attacking is tale-behavior.
examining is tale-behavior.
Pulling is tale-behavior.
Pushing is tale-behavior.
Cutting is tale-behavior.
 
Understand "headbutt [something]" and "smash [something]" as attacking when the location is DAN5.
 
Instead of doing anything except tale-behavior when the tale-straitjacket is worn (this is the tale-bound rule):
    say "You'd need your hands for that."
 
Section Lightbulb
 
[the puzzle - breaking the lightbulb to get free of the straitjacket]
 
The tale-mesh is scenery in DAN5. The printed name is "wire mesh". Understand "wire" and "corner" and "cage" and "mesh" as the tale-mesh.
 
The description is "A thin, fragile looking wire-mesh cage houses the lightbulb, presumably to keep patients from messing with it. One corner of it has been pulled outward, and the whole thing seems to hold to the ceiling only barely."
 
Instead of doing anything except examining with the tale-bulb when the tale-mesh is on-stage:
    say "The wire mesh is in the way."
 
Instead of doing anything except examining with the tale-mesh when the player is not on the tale-lid:
    say "You can't reach the wire mesh from here."
 
Instead of doing anything except examining with the tale-bulb when the player is not on the tale-lid:
    say "You can't reach the lightbulb from here."
 
Instead of doing anything except examining with the tale-mesh when the player is on the not tale-moved tale-lid:
    say "The height is right, but the bulb and its housing is out of reach in the middle of the room."
 
The tale-bulb is a thing in DAN5. it is scenery. The printed name is "lightbulb". Understand "bulb" and "lightbulb" as the tale-bulb.
 
Instead of doing anything except examining with the tale-bulb when the tale-mesh is on-stage and the player is on the tale-lid:
    say "The wire mesh is in the way."
.
Instead of pulling the tale-bulb:
    try taking the tale-bulb.
 
Instead of pushing the tale-bulb:
    try taking tale-bulb.
 
Instead of attacking the tale-bulb:
    say "You firmly plant your feet on the metal chest. It's good you did all the yoga before you came to the manor (and maybe since?), for you balance perfectly, aim your forehard at the bulb and ... headbutt it. There is a disappointingly low and short shattering sound. The light in the cell goes out, but there is enough room from the door to illuminate it in quite the same way as before. You think you've cut yourself on the face, but feel strangely sure that this wound won't bother you much once you leave this room.";
    remove the tale-bulb from play;
    now the tale-shard is in DAN5.
 
The description of the tale-bulb is "Its an old-fashioned, big, glass one."
 
The tale-shard is a thing. The printed name is "glass shard". The initial appearance is "A big shard of glass lies here, in a pool of his useless smaller brothers." Understand "shard" and "glass" as the tale-shard.
 
Instead of taking the tale-shard when the tale-straitjacket is worn by the player:
    say "You nimbly pick up the shard with your toes. Again, yoga.";
    now the tale-shard is carried by the player.
 
 
Section Scene
 
 
Tale-scene is a scene. Tale-scene begins when the location is DAN5 for the first time.
 
Tale-scene ends when the the tale-switch is switched off.
 
When tale-scene begins:
    now everything worn by the player is in the tale-chest;
    now everything carried by the player is in the tale-chest;
    now the player is wearing the tale-straitjacket;
    now door16 is locked.
 
Section Chest
 
[This chest will contain all the inventory the player acquired before. And it needs to be pushed to the middle of the room to reach the lightbulb.]
 
The tale-chest is a container. The tale-chest is openable and closed. The printed name is "metal chest". The initial appearance of the tale-chest is "A metal chest stands in a corner of the room."
 
Understand "metal chest" and "chest" as the tale-chest.
 
The tale-lid is an enterable supporter. It is scenery. The printed name is "metal chest". The tale-lid is in DAN5.
 
The tale-chest is in DAN5.
 
The description of the tale-chest is "[if open]A metal, military looking chest with a lot of complicated snaps.It's open.[otherwise]A metal, military looking chest with a lot of complicated snaps.The lid doesn't close fully. Through the crack you can see [a random thing in the tale-chest].[line break][end if]
[if the tale-straitjacket is worn]No way you'll open it while stuck in this damn strait jacket.[end if]"
 
The tale-crack is part of the tale-chest. Understand "crack" as the tale-crack. The printed name is "crack". The description is "[if the tale-shard is not in the tale-crack]The lid doesn't close fully and leaves a small crack.[otherwise]The glass shard is stuck in the crack, with the shard part pointing outwards.[end if]". The tale-crack is a container. The tale-crack is opaque.
 
Check inserting something into the tale-crack:
    if the noun is not the tale-shard:
        say "That won't fit in there." instead;
    otherwise:
        continue the action.
 
Check taking the tale-chest:
    say "Oof. Too heavy, even when you lift with your knees." instead.
 
Check entering the tale-chest:
        try entering the tale-lid instead.
 
Report entering the tale-lid when the tale-straitjacket is worn:
    say "It's surprisingly hard to do without your hands, but you manage to climb onto the chest. The metal is cold beneath your feet.";
    stop the action.
 
Report getting off the tale-lid:
    say "You get off the chest less than elegantly."
 
The tale-lid can be tale-moved. The tale-lid is not tale-moved.
 
Carry out pushing the tale-chest:
    If the tale-lid is tale-moved:
        say "You like the chest where it is, in the middle of the room.";
    otherwise:
        say "It's hard, knee-aching work, as you half-squat and push the heavy chest with your thigh and shin. After a few painfully slow minutes full of an awful metal screeching, the chest is roughly in the middle of the room. Your leg begins to throb slightly, but you feel that pain will be forgotten as soon as you leave this room.";
        now the tale-lid is tale-moved.
 
Report pushing the tale-chest:
    stop the action.
 
Check pulling the tale-mesh:
    if the player is on the tale-moved tale-lid:
        say "Since you don't have the use of your hands, you do a little jump and bite down on the edge of the mesh as hard as you can. You hang in the air for the fraction of a second before gravity does its work and the mesh is pulled down and you land on your shoulder awkwardly. (Here's hoping you didn't fall on your shoulder in an earlier room as well.)[line break]Even though you cut your lip a little, from where you lie on the ground you can see the solitary lightbulb, shining it's dim light, free of its cage.";
        now the player is in DAN5;
        remove the tale-mesh from play;
        stop the action;
    otherwise:
        say "You can't reach it from here." instead.
 
Instead of inserting the tale-shard into the tale-crack:
    now the tale-shard is in the tale-crack;
    say "You gently push the shard into he crack (with your foot) and it fits snugly, with the sharp end pointing outwards conveniently.".
 
Section Straightjacket escape
 
[I tried to make the 'cut straitjacket on shard' puzzle work with only the standard "cut" command. This should do the trick.]
 
Check cutting the tale-straitjacket:
    if the tale-shard is not on-stage:
        say "That seems to be your only hope of escaping that thing, but how?" instead;
    if the tale-shard is not in the tale-crack:
        say "Even with your nimbleness (yoga), you can't quite hold the shard in a way that woud allow you to cut the straitjacket (which is made of thick cotton)." instead;
    If the tale-shard is in the tale-crack:
        say "You kneel and begin to rub the back of the straitjacket, where the arms are tied behind your back, against the shard of glass. It's slow, dull, throbbing work. After endless minutes you feel the jacket giving some room in your shoulders, and with some more cutting and wriggling the fabric finally gives. You rub your arms for a good minute, willing feeling back into them. Finally, you can feel your aching fingers again. Okay, time to get out of here. Somehow.";
        remove the tale-straitjacket from play;
        stop the action.
 
Section Escape
 
The tale-padding is scenery in DAN5.
 
The tale-switch is a device. The Tale-switch is switched on. The description is "It's nothing but a small, unremarkable switch." The initial appearance is "A secret compartment in the wall has swung open, revealing a small switch and some graffiti that says 'THEY THOUGHT THEY COULD TRAP ME IN MY OWN CELL'."
The printed name is "switch". Understand "switch" as the tale-switch.
 
 
After switching off the tale-switch:
    now door16 is unlocked;
    say "You hear a promising click from the door."
 
After switching on the tale-switch:
    now door16 is locked;
    say "You hear a disheartening *chunk* of a bolt in the door sliding in place."
 
 
Section Venus Path
 
[This is my venus path contribution]
 
The tale-trophy is a thing. The printed name is "trophy for a dog race". The description is "It's a trophy, depicting of a greyhound in mid-jump. The plague reads: To  'Jonathan B. Cragne, Puce Alderman of the Variegated Court, for winning the Cragne Village Dog Race with [italic type]Bloodfang[roman type]."
Understand "trophy" and "greyhound" and "grayhound" as the tale-trophy.
 
 
 
Part 2 Tests not for release - don't let Ryan & Jenni see this! Hi Ryan and Jenni, I'll probably forget to remove this)
 
 
 
test me with "push chest / get on chest / pull mesh / get on chest / headbutt bulb / take shard / put shard in crack / cut jacket / x padding / turn knob / switch off switch / open door / s"