Cragne Manor room M3F5: Branching Corridor (Zachary Hodgens)

This file is part of the Cragne Manor source code collection. Posted with the author's permission. All rights reserved.


"cragne manor room m3f5" by Zachary Hodgens
 
Chapter 1 - Do Not Change Any Of This
 
[Include Cragne Suite by Ryan Veeder.]
 
[Don't mess with other people's rooms!]
 
M3F is a region.
 
M3F5 is a room in M3F. M3F5 is southeast from M3F6 and northwest from M3F7 and east from M3F4 and west from M3F1.
 
Part 1 - M3F5 Twisty Passage
 
Printed name of M3F5 is "Branching Corridor (Zachary Hodgens)".
 
Description of M3F5 is "A trace amount of sunlight filters in impossibly through imperceivable cracks in the ceiling, illuminating the barren wooden walls and floorboards of this narrow passageway. A short distance away you find yourself in a crossroads of sorts. [if cactusvariable is 0]Corridors leading elsewhere go off toward the northwest, west, and east. Another corridor to the southeast dead-ends suddenly, blocked by a pair of large potted cacti.[otherwise if cactusvariable is 1]Corridors leading elsewhere go off toward the northwest, west, and east. The corridor to the southeast is still impeded, now by a second pair of large potted cacti.[otherwise if cactusvariable is 2]Corridors leading elsewhere go off toward the northwest, west, east, and southeast. Several large potted cacti line the walls of the passageways."
 
Instead of going southeast:
    if cactusvariable is not 2:
        say "Your path is blocked improbably by a hallway full of large potted cacti. You'd rather not get a face full of spikes, so you're going to need to make some room to get by.";
    if cactusvariable is 2:
        say "You carefully sidestep through the maze of cacti you have built.";
        move player to M3F7.
 
A gold cactus is here. A gold cactus is fixed in place. Instead of taking gold cactus, say "It's far too large and heavy to pick up, but you could probably move it around with some force."
 
Instead of eating gold cactus, say "You're not willing to take that risk."
 
Instead of cutting gold cactus, say "You wouldn't even begin to know the most appropriate way to go about cutting this cactus."
 
Instead of pulling gold cactus:
    if gold cactus is scenery:
        say "The gold cactus is fine where it is now.";
    if gold cactus is not scenery:
        say "If you pull it backwards you'll end up blocking the way to the rest of the corridors.".
 
Description of gold cactus is "On the left side of the hallway is a gold cactus. This cactus is lacking a center trunk, and instead is a mass of many mid-length stems branching out of the soil. Every inch of this cactus is covered in sharp-looking spikes. The light filtering in from above gives the cactus a golden hue."
 
Instead of pushing gold cactus:
    if gold cactus is scenery:
        say "The gold cactus will not budge from this spot.";
    if gold cactus is not scenery:
        say "You push the gold cactus a few feet forward before it bumps into an object behind it. You still can't pass, but now you have a better angle to approach the fuzzy cactus." ;
        now gold cactus is scenery.
 
A fuzzy cactus is here. A fuzzy cactus is fixed in place. Instead of taking fuzzy cactus, say "It's far too large and heavy to pick up, but you could probably move it around with some force."
 
Instead of eating fuzzy cactus, say "You're not willing to take that risk."
 
Instead of cutting fuzzy cactus, say "You wouldn't even begin to know the most appropriate way to go about cutting this cactus."
 
Instead of pulling fuzzy cactus, say "There's little room to do that, maybe you should push it instead."
 
Description of fuzzy cactus is "On the right side of the hallway is a fuzzy cactus. A single trunk comes up from the soil and branches out in to a multitude of branches in all directions. The branches are covered in tiny spikes that give the cactus an overall fuzzy appearance."
 
Instead of pushing fuzzy cactus:
    if fuzzy cactus is scenery and gold cactus is scenery:
        say "The fuzzy cactus is good where it is.";
    if gold cactus is scenery:
        say "From this side you can get close enough to the fuzzy cactus to push it into an alcove in the side of the hallway, clearing the path toward the southeast exit.";
        now fuzzy cactus is scenery;
        now cactusvariable is 1;
        say "[paragraph break]Unfortunately, a second pair of cacti block your path behind the first. This time it's a tall cactus and a flowering cactus.";
        move tall cactus to M3F5;
        move flowering cactus to M3F5;
    if gold cactus is not scenery:
        say "A large group of branches looms out toward you. Upon closer inspection, the diminutive spikes that give the cactus its fuzzy appearance look like innumerable, tiny hooks. It's impossible to get close enough to the base of the fuzzy cactus planter to push it from this angle, not without getting painful barbs all over you.".
 
A tall cactus is a thing. A tall cactus is fixed in place. Instead of taking tall cactus, say "It's far too large and heavy to pick up, but you could probably move it around with some force."
 
Instead of eating tall cactus, say "You're not willing to take that risk."
 
Instead of cutting tall cactus, say "You wouldn't even begin to know the most appropriate way to go about cutting this cactus."
 
Instead of pulling tall cactus, say "You've got a mess of cacti behind you already, it's probably better to push this out of the way instead."
 
Description of tall cactus is "On the left side of the hallway is a tall cactus. Now this is a very traditional-looking cactus. It has a tall green center trunk and two large branches bent at right angles, as if the cactus was flexing its arms at you."
 
Instead of pushing tall cactus:
    if tall cactus is scenery and flowering cactus is scenery:
        say "You're about worn out from all this physical labor. You leave the tall cactus where it is.";
    if flowering cactus is scenery:
        say "Maneuvering around its large spiky arm, you are able to get to a vantage point where you force the tall cactus out of the hallway into another alcove in the wall. The path to the southeast is finally clear!";
        now tall cactus is scenery;
        now cactusvariable is 2;
    if flowering cactus is not scenery:
        say "One of big arms of the tall cactus is jutting out in your direction in such a way that it's impossible to get close enough to push it from this angle without getting a face full of spikes.".
 
A flowering cactus is a thing. A flowering cactus is fixed in place. Instead of taking flowering cactus, say "It's far too large and heavy to pick up, but you could probably move it around with some force."
 
Instead of eating flowering cactus, say "You're not willing to take that risk."
 
Instead of cutting flowering cactus, say "You wouldn't even begin to know the most appropriate way to go about cutting this cactus."
 
Description of flowering cactus is "On the right side of the hallway is a flowering cactus. This is the kind of cactus that is made up of a whole bunch of teardrop-shaped paddles that tessellate out from its base. In the light you can see that flowers have started to bloom at its tips."
 
Instead of pushing flowering cactus, say "There's a wall behind the flowering cactus that prevents you from pushing it any further forward."
 
Instead of pulling flowering cactus:
    if flowering cactus is scenery:
        say "It's out of the way now, you don't need to be too picky about where you leave it.";
    if flowering cactus is not scenery:
        say "You pull the flowering cactus back several feet, giving you enough room to get by and access a safer side of the tall cactus.";
        now flowering cactus is scenery.
 
Cactusvariable is a number that varies. Cactusvariable is initially 0.
 
Every turn while location is M3F5:
    if the player has been in M3F5 for only 0 turns:
        say "The trace rays of sunlight beaming down from above get in your eyes.";
    if the player has been in M3F5 for only 1 turns:
        say "The sunlight shining down is still in your eyes, no matter where you turn your head. A bead of sweat slides down your face.";
    if the player has been in M3F5 for only 2 turns:
        say "The sun will not let up. Was it even sunny outside before you entered the mansion? How long have you been in here? You're beginning to distrust your recollection of events so far.";
    if the player has been in M3F5 for only 3 turns:
        say "The sun continues to assault your senses. Your eyes are beginning to lose focus and you are sweating profusely. The air is so dry in here, it's unbearable.";
    if the player has been in M3F5 for only 4 turns:
         say "The sun is unyielding. You have lost the context of even the idea of 'cold'. Heat is your new reality.";
    if the player has been in M3F5 for only 5 turns:
        say "Despite everything you know, things continue to get even hotter. It is as if the sun itself is being drawn closer to the surface of the Earth, closer to you.";
    if the player has been in M3F5 for only 6 turns:
        say "The sun is almost here now. You can feel its radiance burning in every cell of your body. You can see its imperishable light beaming in through every crack and seam of the room.";
    if the player has been in M3F5 for only 7 turns:
        say "Four and a half billion years ago, a swirling mass of hydrogen and helium became a shinging beacon of light in an endless universe of darkness. It brought together a collection of space debris that over the aeons became a set of planets all its own. Its light allowed life to flourish on one of these planets: your planet. The sun has spent billions of years of effort all to arrive at this moment: the moment where it finally gets to meet you! [paragraph break]The sun is here now. At long last you feel your body evaporating in its absolute light. All at once you are rejoined with your divine creator and you are no more.";
        end the story