Cragne Manor room MGR1: Front Walk (Matt Weiner)

This file is part of the Cragne Manor source code collection. Posted with the author's permission. All rights reserved.


"Cragne Manor Porch" by Matt Weiner
 
Chapter 1 - Do Not Change Any Of This
 
Use unabbreviated object names.
 
Include Cragne Suite by Ryan Veeder.
 
[Don't mess with other people's rooms!]
 
MGR is a region.
 
MGR1 is a room in MGR. MGR1 is north of DAN8.
 
MGR1a is a room in MGR. MGR1a is north of MGR1.
 
Door4 is a closed locked scenery door. Door4 is inside from MGR1a and outside from M1F1. [It also makes sense to think of the door as being north of MGR1 and south of M1F1.] Key4 unlocks Door4.
 
Key4 is in CHU5.
 
MGR2 is a room in MGR. MGR2 is northwest of MGR1.
 
MGR6 is a room in MGR. MGR6 is northeast from MGR1.
 
Part - MGR1 Porch
 
Section 1 - weiner-rooms
[for defining things that only happen in my rooms]
 
[every contributor's rooms needed an identifier to avoid giving the same name to two things. I chose my last name, "weiner," for the obvious dumb jokes. Hopefully this is the sort of joke that accumulates power with repetition, because it's going to be repeated a lot.]
 
A weiner-room is a kind of room. MGR1 and MGR1a are weiner-rooms.
 
Instead of examining the player in a weiner-room, say "You're tired and muddy from the trudge up to the manor."
 
Instead of examining the player in a weiner-room when the weiner clogs are weiner-wiped, say "You're tired from the trudge up to the manor, but a bit less muddy than you were."
 
Section 2 - testing stuff not for the main product
 
[Include Object Response Tests by Juhana Leinonen.
 
The player carries a weiner-test-pebble.
 
When play begins:
    repeat with item running through things:
        say "[item]." [for seeing what things need printed names, because I left in several weiners. DEFFO do not leave this in the version I send Ryan and Jenni.]]
 
Chapter 3 - Front Walk
 
[nothing interactive or significant will be here but there will be an object with jokes about Shelburne, VT, except I will call it Stowe because no one has heard of Shelburne]
 
Printed name of MGR1 is "Front Walk (Matt Weiner)".
 
Description of MGR1 is "Cragne Manor looms to the north. Its light gray marble front is marred by a screened-in wooden porch, clearly tacked on well after the manor was built. A gravel path bends around the manor to the northeast and northwest, and the driveway leads south back to town."
 
Section 1 - The Manikin
 
A strange little weiner harvest manikin is fixed in place in MGR1. "By the porch steps is a post with a placard reading '31.' A strange little manikin is affixed to it." The printed name of the strange little weiner harvest manikin is "strange harvest manikin". The description of the strange little weiner harvest manikin is "A faceless three-foot straw figure in a flowered bonnet and plaid skirt. It looks like a figure from some ancient harvest rite--somewhat like the harvest manikins in Stowe outside such establishments as The Startled Cat, The Buxom Crow, The Ambulatory Barnacle, and Tweebones."
 
The weiner placard is scenery in MGR1. Understand "post" as the weiner placard. The printed name of the weiner placard is "placard". The description of the weiner placard is "It reads '31.' The house address, presumably." Understand "address" as the weiner placard.
 
Before doing anything other than examining or weiner contact when the current action involves the strange little weiner harvest manikin: say "It's just a piece of local whimsy. No need to bother with it.[one of][or][or][or][or][line break][bracket]Honestly, there's nothing to do with the manikin besides looking at it. There isn't really anything to do here but go somewhere else.[close bracket][line break][stopping]" instead.
 
The weiner flowered bonnet is part of the strange little weiner harvest manikin. The description of the weiner flowered bonnet is "It's kind of cute." The printed name of the weiner flowered bonnet is "flowered bonnet".
 
The weiner plaid skirt is part of the strange little weiner harvest manikin. The description of the weiner plaid skirt is "Probably something a six-year-old grew out of." The printed name of the weiner plaid skirt is "plaid skirt".
 
Instead of taking something incorporated by the strange little weiner harvest manikin: say "You don't want to strip the manikin of its clothing."
 
Section 2 - The Porch as seen from outside
 
The weiner-porch is scenery in MGR1. The printed name of the weiner-porch is "porch". Understand "porch" or "mudroom" or "mud room" or "screened" or "screened-in" or "wooden" or "wood" or "screens" or "thick screens" or "stairs" or "steps" or "flight" as the weiner-porch when the location is MGR1. The description of the weiner-porch is "A brief flight of steps leads up to the porch. The thick screens block any view inside."
 
Instead of going up when the location is MGR1: try going north.
Instead of going inside when the location is MGR1: try going north.
Instead of entering the weiner-porch: try going north.
Instead of climbing the weiner-porch: try going north.
 
After going north from MGR1:
    say "You climb the steps to the porch.";
    continue the action.
 
Instead of getting off the weiner-porch: say "You're already outside [the weiner-porch]."
 
Instead of looking under or searching the weiner-porch: say "Under the porch are only mud and leaves."
 
The weiner mud is scenery in MGR1. The printed name of the weiner mud is "mud". Understand "leaves" or "mud and leaves" or "leaves and mud" as the weiner mud. [have to put the "and"s in explicitly or it'll think we're examining multiple objects.] The description of the weiner mud is "Under the porch are only mud and leaves."
 
Section 3 - The Manor as seen from outside
 
The weiner manor front is scenery in MGR1. The printed name of weiner manor front is "manor". The description of the weiner manor front is "Its windows are dark in its light gray front. Marble from the Barre quarry, you think. Was there a legend about a worker who was crushed under a slab, and a stain that would never come out? In this light you can't see it."
 
Understand "windows" or "window" or "marble" or "light" or "gray" or "dark" or "marble" or "cragne" as the weiner manor front.
 
The weiner blood stain is part of the weiner manor front. The printed name of the weiner blood stain is "supposed bloodstain on the outside walls".
 
Before doing anything when the current action involves the weiner blood stain: say "You don't see a stain at all. Not even a trick of the light." instead.
Understand "slab" or "worker" or "bloodstain" as the weiner blood stain.
 
Section 4 - Miscellaneous exits and stuff
 
The weiner gravel path is scenery in MGR1. The printed name of the weiner gravel path is "gravel path". The description of the weiner gravel path is "The gravel path curves around the manor to the northeast and northwest."
 
The weiner driveway is scenery in MGR1. The printed name of the weiner driveway is "driveway". Understand "walk" or "drive" or "way" as the weiner driveway. The description of the weiner driveway is "The driveway leads south back to town."
 
Chapter 4 - Front Porch
 
Section 1 - The porch as seen from inside
 
Printed name of MGR1a is "Mudroom (Matt Weiner)".
 
Description of MGR1a is "The porch is a mudroom, a place for taking off coats and muddy shoes[first time]--though you're not eager to change into any strange shoes[only]. The marble front wall seems like a sheer cliff face, the porch like a flimsy shelter built onto it. The front door leads inside to the north."
 
The weiner screens are plural-named scenery in MGR1a. Instead of examining or searching the weiner screens, say "The walk is a ghostly outline visible through the thick screens." Understand "ghostly" or "walk" or "outline" or "thick" or "window" or "windows" or "screen" as the weiner screens. The printed name of the weiner screens is "screens".
 
Instead of opening or pulling or pushing the weiner screens: say "There's no way to open the screens."
 
Instead of closing the weiner screens: say "They're already closed."
 
The weiner front wall is scenery in MGR1a. Understand "gray" or "grey" or "marble" or "house" or "manor" or "Cragne manor" as the weiner front wall. The description of the weiner front wall is "Gray Barre marble, smooth and cold." The printed name of the weiner front wall is "front wall".
 
The weiner ceiling is scenery in MGR1a. The description of the weiner ceiling is "The ceiling is made of the same white boards as the rest of the porch." The printed name of the weiner ceiling is "ceiling".
 
Before doing something to the weiner ceiling when the action requires a touchable noun: say "You can't reach the ceiling, and there doesn't seem to be much reason to try." instead.
 
Before doing something when the second noun is the weiner ceiling and the action requires a touchable second noun: say "You can't reach the ceiling, and there doesn't seem to be much reason to try." instead.
 
The weiner floor is scenery in MGR1a. The description of the weiner floor is "The floor is made of white boards scuffed with mud." Understand "white" or "boards" or "scuffed" or "mud" as the weiner floor. The printed name of the weiner floor is "floor".
 
Instead of examining a direction in MGR1a:
    if the noun is:
    -- north:
        try examining the weiner front wall;
    -- inside:
        try examining the weiner front wall;
    -- up:
        try examining the weiner ceiling;
    -- down:
        try examining the weiner floor;
    -- otherwise:
        try examining the weiner screens.
 
Instead of going outside in MGR1a: try going south.
Instead of going down in MGR1a: try going south.
Instead of exiting in MGR1a: try going south.
 
Instead of going north in MGR1a: try going inside.
 
The weiner-mudroom is scenery in MGR1a. Understand "porch" or "mudroom" or "mud room" as the weiner-mudroom when the location is MGR1a. The printed name of the weiner-mudroom is "mudroom".
Instead of examining the weiner-mudroom: try looking.
Instead of getting off the weiner-mudroom: try going south.
 
section 2 - the door
 
Door4 is improper-named. [cleared with The Person On The Other Side Of The Door.]
 
Instead of examining Door4 when the location is MGR1a:
    say "The front door is made of heavy dark wood with bronze bands across it. The enormous lock plate is also bronze. Bronze numbers reading 31 are screwed into the door, though surely no one could see them from the road."
 
For printing the name of Door4 when the location is MGR1a: say "front door".
 
Understand "front" or "door" or "heavy" or "dark" or "wood" or "bronze" or "bands" as Door4 when the location is MGR1a.
 
[The following things would be part of the door, but I don't know what it's like from the other side.]
 
A fake-weiner-door-part is a kind of thing. A fake-weiner-door-part is always scenery.
 
The weiner bronze numbers are a fake-weiner-door-part in MGR1a. The weiner bronze numbers are plural-named. The description of the weiner bronze numbers is "Bronze numbers reading 31, weathered green, and almost certainly useless if their purpose is to tell the emergency services that they're at the right house." The printed name of the weiner bronze numbers is "bronze numbers". Understand "weathered" or "green" or "31" as the weiner bronze numbers.
 
The enormous bronze weiner lock plate are a fake-weiner-door-part in MGR1a. The description of the enormous bronze weiner lock plate is "It looks like the sort of old-fashioned keyhole that you could poke a key out of from the other side. If there were a key in it, which there doesn't seem to be." Understand "keyhole" and "hole" and "key hole" as the enormous bronze weiner lock plate. The printed name of the enormous bronze weiner lock plate is "lock".
For printing the name of the enormous bronze weiner lock plate while asking which do you mean: say "bronze lock plate".
 
Instead of searching the enormous bronze weiner lock plate: say "It's too dark to see through the keyhole."
 
Instead of inserting key4 into the enormous bronze weiner lock plate:
    if door4 is locked:
        try unlocking door4 with key4;
    otherwise:
        say "The door is already unlocked."
 
Instead of taking a fake-weiner-door-part: say "[regarding the noun][They] [are] part of the door."
 
The enormous bronze weiner lock plate can be weiner-examined. [for a gag about pulling the welcom mat]
Carry out examining the enormous bronze weiner lock plate: now the enormous bronze weiner lock plate is weiner-examined.
 
Door4 can be ever-weiner-opened. [for the same gag; it should trigger when we examine the lock and pull the welcome mat, as long as the welcome mat has never been pulled and the door has never been opened.]
 
Carry out opening Door4: now door4 is ever-weiner-opened.
 
Instead of looking under Door4 when the location is MGR1a:
    if the weiner welcome mat is weiner-pulled:
        say "You see only darkness.";
    otherwise:
        say "The welcome mat is under the door."
 
section 3 - hooks
 
The weiner hooks are a privately-named plural-named fixed in place supporter in the MGR1a. The printed name of the weiner hooks is "hooks". Understand "hook" and "hooks" and "strange" and "strangely shaped" and "black" and "metal" and "iron" and "two"as the weiner hooks.
 
To hang is a verb.
 
Instead of examining the weiner hooks:
    if two things are on the weiner hooks:
        say "[A list of things that are on the weiner hooks] [hang] from the wall. The hooks are hidden beneath them.";
    otherwise if a thing (called the item) is on the weiner hooks:
        say "A black metal hook protrudes from the wall, twisting in strange ways, like the outline of the human form projected through some alien dimension. [An item] [hang] beside it.";
    otherwise:
        say "Two black metal hooks protrude from the wall, twisting in strange ways, like the outline of the human form projected through some alien dimension. Or perhaps the Cragnes simply wanted hooks that could hold any item of clothing.";
    if the weiner shadow is in MGR1a:
        say line break;
        say "The floor below the hooks is lost in an unusually deep black shadow."
 
The weiner calfskin coat is on the weiner hooks. The weiner calfskin coat is wearable. The printed name of the weiner calfskin coat is "calfskin coat". The description of the weiner calfskin coat is "A thigh-length belted calfskin coat, clean as if it's never been outside."
The pockets of the weiner calfskin coat are a plural-named container. The pockets of the weiner calfskin coat is part of the weiner calfskin coat. Understand "pocket" as the pockets of the weiner calfskin coat. The printed name of the pockets of the weiner calfskin coat is "pockets of the calfskin coat".
 
Does the player mean doing something with the pockets of the weiner calfskin coat: it is unlikely. [not only may this redirect the parser's attention to more important pockets, it keeps "x coat" out of a disambiguation loop. Unless there's another coat, in which case the player had bloody well mean that one.]
For clarifying the parser's choice of the weiner calfskin coat: do nothing. [risky but it should bop "(the calfskin coat)" when the player enters "x coat"]
 
Instead of searching the weiner calfskin coat: try searching the pockets of the weiner calfskin coat.
 
Understand "hang [something] from/on [something]" as putting it on when the location is MGR1a.
 
The carrying capacity of the weiner hooks is two.
 
For writing a paragraph about the weiner hooks:
    if the weiner hooks support nothing:
        say "In one corner of the porch two strangely shaped metal hooks are fastened to the wall.";
    otherwise if the weiner hooks support two things:
        let L be the list of things supported by the weiner hooks;
        let item one be entry 1 of L;
        let item two be entry 2 of L;
        say "[An item one] and [an item two] hang on the wall in one corner of the porch.";
    otherwise: [they support one thing]
        let item be a random thing supported by the weiner hooks;
        say "In one corner of the porch a strangely shaped hook is fastened to the wall. [An item] [hang] beside it.";
    if the weiner cloak of darkness is in MGR1a:
        say line break;
        say "Beneath lies a [weiner cloak of darkness], so dark it seems to be a mere shadow."
 
Before putting something (called the possible clothing) on the weiner hooks when the possible clothing is not wearable: say "The hooks are for clothing--coats and cloaks, especially." instead.
 
[and eventually there will be some shoes lying around and a Cloak Of Darkness covering a shoe and you have to have to pick up the Cloak of Darkness to reveal a boot but the Cloak drives you Mad and if you drop it it just goes back on the boot so you have to hang it up on the hook and then you can search the boot to find the macguffin but I haven't implemented any of that yet because I've been busy with shoe-wiping]
[lol the macguffin is on the table and the other boot contains a dumb joke]
 
Section 4 - Other footwear
 
A pair of weiner slippers is wearable in MGR1a. The pair of weiner slippers is ambiguously plural. Understand "blue" or "cloth" or "shoes" or "lightly" or "scuffed" or "slipper" as the pair of weiner slippers. The printed name of the pair of weiner slippers is "pair of blue cloth slippers".
 
The description of the pair of weiner slippers is "A lightly scuffed pair of indoor slippers."
 
A weiner-boot is a kind of thing. A weiner-boot is always wearable.
For printing the plural name of a weiner-boot: say "boots".
Understand "boots" as the plural of a weiner-boot. Understand "pair of/--" as the plural of a weiner-boot. [They will be listed in the inventory as "pair of leather boots" if you've got them both and this should allow "drop pair of leather boots"]
 
A single weiner boot is a weiner-boot in MGR1a. The printed name of the single weiner boot is "single brown leather boot". Understand "brown" or "leather" or "shoe" or "shoes" or "muddy" or "sole" or "first" as the single weiner boot.
 
For writing a paragraph about the pair of weiner slippers when the location is MGR1a:
    say "Against the front wall are a pair of blue cloth slippers[if the single weiner boot is in MGR1a] and [a single weiner boot][end if]." [in MGR1a--it has to be right in the location, not on the hook or table or anything.]
 
Check wearing the pair of weiner slippers when the location is a weiner-room: say "You don't want to change into strange slippers." instead. [I had thought it would be within the spirit of the game to have the player able to wear more than one pair of shoes at once, but this bugged the testers.
HOWEVER, if the player takes these shoes elsewhere, they will be able to wear them. And then if they come back, the clogs will magically reappear! So there.]
 
The description of the single weiner boot is "One leather boot with a muddy sole."
 
For writing a paragraph about the single weiner boot when the location is MGR1a and the pair of weiner slippers is not in MGR1a:
    if the matching weiner boot is not in MGR1a:
        say "A single boot stands against the front wall.";
    otherwise:
        say "One boot stands against the front wall; its mate lies under the hooks.";
        now the matching weiner boot is mentioned.
 
 
Section 5 - The Cloak OF DARKNESS
 
[first a dummy item that will be replaced with the cloak when the time is right]
The weiner shadow is scenery in MGR1a. The printed name of the weiner shadow is "shadow". Understand "unusually" or "deep" or "black" or "floor" as the weiner shadow when the location is MGR1a.
 
Before doing anything when the current action involves the weiner shadow:
    say "It is no mere shadow on the floor, but a crumpled cloak, of a black so black that its folds cannot be seen.";
    now the weiner shadow is nowhere;
    now the weiner cloak of darkness is in MGR1a;
    stop the action.
 
The weiner cloak of darkness is wearable. The printed name of the weiner cloak of darkness is "black cloak". Understand "black" or "deep" as the weiner cloak of darkness. [the cloak shouldn't be able to get out of MGR1a but let's write it safely--actually someone might be able to stuff it in something]
 
The description of the weiner cloak of darkness is "A cloak so black it seems to absorb the light around it."
 
After taking the weiner cloak of darkness when the matching weiner boot is nowhere: [I think this should be safe because no one is allowed to code an object-destroyer, but if they do, hey, the boot will come back]
    now the matching weiner boot is in MGR1a;
    say "[one of]Taking the cloak reveals a leather boot, mate to the first one[or]Taking the cloak again reveals the leather boot[stopping]."
 
[the cloak kills you]
 
The weiner doom count is initially 3.
 
Every turn when the player holds the weiner cloak of darkness:
    if the weiner doom count is:
        -- 3:
            say "The cloak tingles strangely in your hands.";
        -- 2:
            say "Your hands begin to feel numb where they touch the cloak.";
        -- 1:
            say "You can't feel your hands anymore. Looking down, you can't see them either. They have vanished into darkness--and the darkness is creeping up your arms.";
        -- 0:
            say "Your body feels lost. You look down and see nothing but darkness moving closer to you. Soon you see and feel nothing at all.";
            end the story saying "You have been lost to the darkness";
    decrement the weiner doom count.
 
Every turn when the player does not hold the weiner cloak of darkness and the weiner doom count is not 3:
    say "Your senses return to normal.";
    now the weiner doom count is 3.
 
Instead of wearing the weiner cloak of darkness:
    say "You seem to be pulling on darkness itself. Where the cloak touches your body, both disappear. The cowl settles over your head, and with it come darkness... numbness... and then nothing at all.";
    end the story saying "You have been lost to the darkness".
 
[you can't do anything but solve the puzzle while you have it]
 
Dropping or examining or wearing the weiner cloak of darkness is paying attention to the cloak.
Putting the weiner cloak of darkness on something is paying attention to the cloak.
 
First before doing anything other than paying attention to the cloak when the player holds the weiner cloak of darkness: say "The cloak clouds your mind so, you can think of nothing else while you hold it." instead. [has to be first before to jump in front of all the other stuff I blocked using Before. Which might have been a bad idea.]
 
Before putting the weiner cloak of darkness on something when the second noun is not the weiner hooks:
    say "The cloak seems to resist going on [the second noun], as though [they] [are] not a suitable place for it to rest." instead. [just so you can't drape it on the table]
 
After dropping the weiner cloak of darkness when the location is MGR1a:
    say "You find yourself crumpling the cloak under the hooks where you found it[if the matching weiner boot is in MGR1a], concealing the boot from sight[end if].";
    if the matching weiner boot is in MGR1a:
        now the matching weiner boot is nowhere.
 
[I think the backstory here is:
    someone came to the manor wearing their eldritch cloak of darkness
    at the time there was another coat hung up so they tossed the coat on the floor, covering that boot
    then they realized they didn't have the key
    they shoved the welcome mat under the door and poked the lock, but no luck
    they got frustrated and went away, forgetting their cloak]
 
Section 6 - The Matching Boot
 
The matching weiner boot is a weiner-boot. The printed name of the matching weiner boot is "mate of the first leather boot". Understand "mate" or "brown" or "leather" or "shoe" or "shoes" as the matching weiner boot.
The indefinite article of the matching weiner boot is "the". [we always want "the mate of the first leather boot," not "a mate...."]
 
[It looks weird if you have "the mate of the first leather boot" listed before "a single leather boot," and ordinarly the inventory listing goes in reverse order you picked it up, so we include this fairly redundant bit of frippery]
Before listing contents: unless the number of worn weiner-boots is 1, group weiner-boots together. [If they're wearing one and carrying one, list them together]
Rule for grouping together weiner-boots when the listing group size is 2: say "a pair of leather boots[if the player wears a weiner-boot] (being worn)[end if]".
 
The description of the matching weiner boot is "A brown leather boot like the first, but without the mud[first time][if the weiner slip of paper is nowhere]. You think you glimpse something behind its pulled-out tongue[end if][only]."
 
The weiner slip of paper is a thing. The printed name of the weiner slip of paper is "slip of paper".
 
Instead of searching the matching weiner boot when the weiner slip of paper is nowhere:
    say "You discover a slip of paper inside the boot.";
    now the player carries the weiner slip of paper.
 
Check wearing the matching weiner boot when the weiner slip of paper is nowhere:
    say "This strange boot doesn't look like it'll fit you, but you do discover a slip of paper inside it.";
    now the player carries the weiner slip of paper;
    stop the action.
 
Check wearing a weiner-boot when the location is a weiner-room:
    say "This is someone else's boot, and it doesn't even look like it'll fit you." instead.
 
Does the player mean doing something with the matching weiner boot: it is likely. [isn't much of a way to distinguish this from the other one, and it's more interesting. It'd be nice to have this run only when the comparison class is the other boot, but we'd need Disambiguation Control for that!]
 
The description of the weiner slip of paper is "It says 'Inspected by Number 8.'"
[You see, I thought that I was supposed to be conveying some text. I was even prepared to roll up a newspaper and stick it in the boot. But I was asked for a teapot, which can't really go in a boot. And I'd already thought of this puzzle. So I put the teapot in plain sight on a table and had the reward for the puzzle be this total macguffin.]
 
Section 7 - Welcome Mat
 
A weiner welcome mat is privately-named in MGR1a. Understand "welcome" and "mat" and "muddy" as the weiner welcome mat. The printed name of the weiner welcome mat is "muddy welcome mat".
 
For writing a paragraph about the weiner welcome mat:
    if the weiner welcome mat is weiner-pulled:
        say "A [if the weiner clogs are not weiner-wiped]slightly [end if]muddy welcome mat lies in front of the door.";
    otherwise:
        say "A [if the weiner clogs are not weiner-wiped]slightly [end if]muddy welcome mat sticks out partway from under the front door."
 
The weiner welcome mat can be weiner-pulled. The weiner welcome mat is not weiner-pulled. [That is, is it halfway under the door?]
The weiner welcome mat can be ever-weiner-pulled. [keeps track of whether we've ever pulled the mat for various descriptions]
The weiner welcome mat can be weiner-prepull-examined. The weiner welcome mat is not weiner-prepull-examined. [Governs whether you get the message when you pull it.]
 
The description of the weiner welcome mat is "[weiner welcome mat description]".
 
The weiner welcome mat can be weiner-turned.
 
Instead of turning the weiner welcome mat:
    if the weiner welcome mat is weiner-pulled:
        say "You turn the welcome mat this way and that.";
    otherwise if the weiner welcome mat is not ever-weiner-pulled:
        now the weiner welcome mat is weiner-turned;
        now the weiner welcome mat is ever-weiner-pulled;
        say "You turn the mat. The other side says 'WEL.' [if the enormous bronze weiner lock plate is weiner-examined and Door4 is not ever-weiner-opened]There's no key on it.[otherwise][line break][end if]";
    otherwise if the weiner welcome mat is weiner-turned:
        now the weiner welcome mat is not weiner-turned;
        say "You turn the mat until you can see the letters 'COME.'";
    otherwise:
        now the weiner welcome mat is weiner-turned;
        say "You turn the mat until you can see the letters 'WEL.'"
 
To say weiner welcome mat description:
    if the weiner welcome mat is weiner-pulled:
        say  "The welcome mat lies crooked in front of the door. It is [if the weiner clogs are weiner-wiped]covered in[otherwise]flecked with[end if] mud. ";
    otherwise:
        say "A [if the weiner clogs are weiner-wiped]muddy [end if]welcome mat sticks partway out from under the front door. [if not ever-weiner-pulled]At least, you suppose it's a welcome mat. The letters you can see spell 'COME.' [end if]" [I am not entirely sure why the spacing goes wonky if I don't put in the extra spaces]
 
Carry out examining the not ever-weiner-pulled weiner welcome mat:
    now the weiner welcome mat is weiner-prepull-examined.
 
Instead of pulling the weiner welcome mat:
    if the weiner welcome mat is weiner-pulled:
        say "The mat is already all the way on the porch. No need to pull it farther.";
    otherwise:
        say "You pull the mat from under the door. [if the weiner welcome mat is weiner-prepull-examined and the weiner welcome mat is not ever-weiner-pulled]It does in fact say 'WELCOME.' [end if] [if the enormous bronze weiner lock plate is weiner-examined and the weiner welcome mat is not ever-weiner-pulled and Door4 is not ever-weiner-opened]There's no key on it.[otherwise][line break][end if]";
        now the weiner welcome mat is weiner-pulled;
        now the weiner welcome mat is ever-weiner-pulled.
 
Carry out opening Door4 when the weiner welcome mat is not weiner-pulled:
    now the weiner welcome mat is weiner-pulled. [so the person doing the other side of the door doesn't have to worry about the welcome mat sticking out. Perhaps there is another way into the manor. If someone sees the welcome mat under the door and then makes their way to the other side and does not see the welcome mat it will be a FASCINATING INCONGRUITY.]
 
Instead of pushing the weiner welcome mat:
    if Door4 is open:
        say "You push the welcome mat around on the porch for a bit. It doesn't reveal anything.";
    otherwise if the weiner welcome mat is not weiner-pulled:
        say "You feel a strange reluctance to push the welcome mat all the way under the door.";
    otherwise:
        now the weiner welcome mat is not weiner-pulled;
        say "You push the welcome mat halfway under the door again." [perhaps include something concerning whether the gag about the key and welcome mat has been deployed]
 
Before taking the weiner welcome mat:
    say "There's no need to stuff a muddy welcome mat into your pockets." instead.
 
Section 8 - Your Shoes
 
The weiner shoebox is a privately-named closed scenery container. [since it's privately-named and scenery the player can't interact with it at all. It's just for holding the shoes.] The weiner clogs are plural-named in the weiner shoebox. The printed name of the weiner clogs is "clogs". The indefinite article of the weiner clogs is "your". Understand "shoes" and "clogs" and "feet" as the weiner clogs.
The printed name of the weiner shoebox is "shoebox (which is an internal construct whose name you shouldn't be seeing, sorry, you can send a transcript of how this happened to authorsfirstname@authorsfirstnameauthorslastname.net)".
 
The weiner shoe boxholder is a privately-named backdrop. The weiner shoebox is part of the weiner shoe boxholder. The weiner shoe boxholder is in MGR1 and MGR1a. The printed name of the weiner shoe boxholder is "shoeboxholder (which is an internal construct whose name you shouldn't be seeing, sorry, you can send a transcript of how this happened to authorsfirstname@authorsfirstnameauthorslastname.net)".
 
After deciding the scope of the player when the location is a weiner-room: place the weiner clogs in scope.
 
Rule for reaching inside the weiner shoebox: allow access. [so the clogs can always be referred to and interacted with in the weiner-rooms.]
 
Before taking or wearing the weiner clogs: say "You're already wearing your shoes." instead.
 
Does the player mean taking off the weiner clogs: it is very likely. [catches "remove shoes," hopefully... for some reason it has to go to "very likely." Oh right, because I defined the matching weiner boot as likely in order to help distinguish it from the single boot]
 
Before taking off or dropping the weiner clogs in MGR1a: [if the player tries "take off feet" they're a jerk]
    say "It might be polite to take off your outside shoes, but you're not going to go into the Manor barefoot. Not in strange shoes, either." instead.
 
Before taking off or dropping the weiner clogs in MGR1:
    say "You're not going barefoot outside." instead.
 
The description of the weiner clogs is "[if weiner-wiped]You've got some of the mud off them.[otherwise]You picked these clogs as sensible walking shoes, but you didn't count on it being this wet. They're caked in mud almost all the way to your ankle[end if]."
 
After taking inventory in a weiner-room: say "You are [if the player holds something]also [end if]wearing a pair of [if the weiner clogs are not weiner-wiped]extremely muddy [end if]clogs[if the weiner clogs are weiner-wiped], still a bit muddy[end if]."
 
Section 9 - Wiping Your Feet
 
Weiner wiping it on is an action applying to two things. [Had to be done!]
 
Understand "wipe [something] on [something]" as weiner wiping it on when the location is a weiner-room.
 
Check weiner wiping something on something when the noun is not the weiner clogs:
    say "Wiping [the noun] on [the second noun] won't do you any good." instead.
 
Check weiner wiping the weiner clogs on something when the second noun is not the weiner welcome mat:
    say "It would be rude to wipe your feet on anything put the welcome mat." instead.
 
Carry out weiner wiping the weiner clogs on the weiner welcome mat:
    try rubbing the weiner clogs.
 
Check rubbing the weiner clogs in MGR1:
    say "The welcome mat [if the weiner welcome mat is known]is[otherwise]must be[end if] in the mudroom." instead.
 
Check rubbing the weiner clogs when the weiner welcome mat is not weiner-pulled:
    say "It'd be awkward to wipe your feet when the welcome mat is halfway under the door. Perhaps you should pull it out first." instead.
 
Instead of entering the weiner welcome mat when the player's command includes "stand":
    say "(wiping your feet on the welcome mat)[command clarification break]";
    try rubbing the weiner clogs.
 
The weiner clogs can be weiner-wiped. The weiner clogs are not weiner-wiped.
The weiner clogs can be never-weiner-wiped. The weiner clogs are never-weiner-wiped. [this is necessary to check whether we're wiping the clogs for the first time, because we need to check that in an After rule and the status gets changed in Carry out.]
 
Carry out rubbing the weiner clogs:
    now the weiner clogs are weiner-wiped.
 
After rubbing the weiner clogs:
    say "You scrape off a bit more mud[first time]. It would require a long session with a brush and water to get it all off, and you doubt you'll find the time[only].".
 
After rubbing the never-weiner-wiped weiner clogs:
    say "A gratifyingly large amount of the mud comes off on the welcome mat.";
    now the weiner clogs are not never-weiner-wiped.
 
Section 10 - The Table and the Teapot
 
[this is the actual puzzle track item. I had thought it would be some text, which would be found in a boot, and then Ben and Jack said that it was a teapot. So the boot puzzle, if I get around to implementing it, will contain a ridiculous and hopefully obvious red herring, and the puzzle item is sitting out on a table. This is probably good from a point of view of going easy on the player.]
 
A weiner small wooden table is fixed in place in MGR1a. [not scenery so we can use the writing a paragraph rule] The printed name of the weiner small wooden table is "table". Understand "deep" and "brown" and "wood" and "stain" as the weiner small wooden table.
 
For writing a paragraph about the weiner small wooden table:
    if the weiner-teapot is on the weiner small wooden table and the number of things on the weiner small wooden table is one: [if the player has been futzing around with putting things on the table, the teapot and everything else gets put in the standard "on the table is" paragraph]
        say "In the other corner of the porch, [a weiner-teapot] sits on a small wooden [weiner small wooden table].";
    otherwise:
        say "In the other corner of the porch is a small wooden table."
 
The description of the weiner small wooden table is "The table is thigh-high, as if sized for a child's tea party, but its deep brown wood is so finely carpentered that the legs and tabletop seem carved from one piece. There is a round brown tea stain on it, but no cups or saucers."
 
The weiner-teapot is on the weiner small wooden table. The printed name of the weiner-teapot is "teapot". Understand "silver" and "teapot" and "tarnished" and "tea" and "pot" as the weiner-teapot. Understand "kettle" and "teakettle" as the weiner-teapot. [because teapots and teakettles are two different things, but people will confuse them.] Understand "Queen Mary" or "from --/the Queen Mary" as the weiner-teapot.
 
For printing the name of the weiner-teapot when asking which do you mean: say "tarnished silver teapot from the Queen Mary". [there were too many things with names like 'adjective adjective noun' so I demoted this to "teapot," but there might be some risk that there's another teapot, so we get this. If the player winds up disambiguating it before examining it that will be suboptimal, but too bad.]
 
The description of the weiner-teapot is "It's a silver teapot tarnished brown on the spout and sides. Through the tarnish you can read the engraving, 'Jane Cragne, RMS Queen Mary, 2 Oct 1942.'"
 
The weiner-teapot-inscription is part of the weiner-teapot. The printed name of the weiner-teapot-inscription is "inscription on the silver teapot". Understand "inscription" and "engraving" as the weiner-teapot-inscription.
 
The description of the weiner-teapot-inscription is "'Jane Cragne, RMS Queen Mary, 2 Oct 1942' is engraved into the silver teapot[first time]. Strange. The Queen Mary had surely been commandeered for the War[only]."
 
Does the player mean doing something with the weiner-teapot-inscription: It is unlikely. [there are probably other engravings and inscriptions, and maybe I don't want to encourage disambiguating to this stupid thing?]
 
Before taking the weiner small wooden table: say "It's a small table, but not small enough to haul around." instead.
 
Instead of pushing or pulling or turning the weiner small wooden table: say "You shift the table around on the porch, to little end."
 
Instead of opening or searching the weiner-teapot: say "There's nothing inside it but a faint brown mark."
 
The faint brown mark is part of the weiner-teapot. The description of the faint brown mark is "A faint brown mark at the bottom of the teapot. From tea, no doubt."
 
The weiner-teapot can be weiner notified.
 
Last report taking the weiner-teapot when the weiner-teapot is not weiner notified: [I'd like to use "handled" for this, but by the time you get to the report taking stage, the teapot is handled, because you just took it! "For the first time" will never print the message if you try and fail to take the teapot, for instance if you pick up the cloak and then the teapot. Doing this in a first time... only substitution tends to insert spurious line breaks when you pick up the teapot subsequent times. So, as with so many things, we use a flag.]
    say "[bracket]This is the only item you need to take from this room or the front walk, and the only other thing you need to do here is unlock the door with the key, when you have it. But there are other things here you can explore, if you like.[close bracket][line break]";
    now the weiner-teapot is weiner notified.
 
Instead of sleeping when the location is a weiner-room:
    say "Tired as you are, you're not sure if you'll be sleeping anytime soon. If you do, it won't be on [if the location is MGR1]the mud[otherwise]the porch[end if]."
 
Section 11 - Locale Priorities
 
[so the things wind up in the order we want -- hooks, table, welcome mat]
 
After choosing notable locale objects when the location is MGR1a:
    set the locale priority of the weiner hooks to 2;
    set the locale priority of the weiner small wooden table to 3;
    set the locale priority of the weiner welcome mat to 4.
 
Section 12 - Responses and Stuff
 
Last instead of going nowhere in MGR1: say "You can go south back to town, northeast or northwest around the manor, or north to the porch."
 
Last instead of going nowhere in MGR1a: say "You can go south back down to the front walk or north in through the front door[if door4 is locked], once you unlock it[end if]."
[has to be last to let the alternate directions work, like going up from the walk]
 
Understand "knock on/-- [something]" as attacking when the location is a weiner-room.
 
To make is a verb.
 
Instead of attacking something when the location is a weiner-room: [mostly for "knock on door"]
    if the noun is:
        -- door4: say "You rap on the door. There is no answer.";
        -- yourself: say "No need for that.";
        -- the weiner cloak of darkness: say "As you strike the cloak, your hand vanishes into darkness. Fortunately it returns when you draw it back.";
        -- the weiner-teapot: say "You tap the teapot. It emits a soft ting.";
        -- the weiner bronze numbers: try attacking door4;
        -- the enormous bronze weiner lock plate: say "You knock sharply on the lock plate. You do not hear the sound of a falling key.";
        -- the weiner front wall: say "You scrape your knuckles on the marble front wall.";
        -- the weiner floor: say "You rap the wooden floorboards.";
        -- the weiner-porch: say "You rap on the wooden porch.";
        -- otherwise: say "You strike [the noun]. [They] [make] no sound."
 
Does the player mean attacking door4 when the location is MGR1a: it is very likely.
 
Instead of thinking when the location is a weiner-room:
    say "You take a breath and try to gather your thoughts."
 
Instead of jumping in MGR1: say "You jump on the soft mud."
Instead of jumping in MGR1a: say "You make a soft thunk on the floorboards."
 
Touching is weiner contact. Rubbing is weiner contact. Squeezing is weiner contact.
[I swear to God I was just going to make that "contact" before I realized I should namespace it.]
 
Instead of weiner contact: [this should be OK because it's only applying to my objects and otherwise continues the action]
    if the noun is:
        -- the weiner clogs: [the one action that does something]
            if the current action is rubbing the weiner clogs:
                continue the action;
            otherwise:
                if the weiner clogs are weiner-wiped:
                    say "You give your foot a squeeze.";
                otherwise:
                    say "But your clogs are caked in mud.";
        -- the strange little weiner harvest manikin:
            say "The manikin makes a crunching sound as you touch it.";
        -- the weiner flowered bonnet:
            say "The bonnet is stiff from being out in all weathers.";
        -- the weiner plaid skirt:
            say "The skirt is worn to the nubs.";
        -- the weiner placard:
            say "The placard's laminated front is smooth.";
        -- the weiner-porch:
            say "The wood of the porch is rough.";
        -- the weiner manor front:
            say "The manor's marble wall is smooth and cool to the touch.";
        -- the weiner blood stain:
            say "The manor's marble wall is smooth and cool to the touch. You can't feel any remnants of dried blood.";
        -- the weiner gravel path:
            say "The gravel digs into your palm.";
        -- the weiner driveway:
            say "The asphalt driveway is rough and cracked.";
        -- yourself:
            say "You pinch yourself. Nope, not dreaming.";
        -- the weiner screens:
            say "The sensation of rubbing the screens is oddly pleasing. Somehow it reminds you of walking next to a fence, running a stick along every picket.";
        -- the weiner front wall:
            say "The manor's marble wall is smooth and cool to the touch.";
        -- the weiner ceiling:
            say "You can't reach the ceiling. It doesn't look like there's anything you need up there.";
        -- the weiner floor:
            say "You scrape a bit of white paint from the floorboards. Not lead, you hope.";
        -- the weiner-mudroom:
            try touching the weiner floor;
        -- the weiner bronze numbers:
            say "You feel the bronze numbers, pitted with age.";
        -- the enormous bronze weiner lock plate:
            say "The lock plate feels smooth and slick.";
        -- the weiner hooks:
            say "The hook is rough and oddly twisted. An ingenious design, though, that could accommodate clothing of any shape.";
        -- the weiner calfskin coat:
            say "The coat feels supple and smooth.";
        -- the pockets of the weiner calfskin coat:
            try touching the weiner calfskin coat;
        -- the pair of weiner slippers:
            say "The soft cloth feels comfortable, though you think you'll keep your own shoes on.";
        -- the single weiner boot:
            say "The boot squeezes under your touch, then pops back to its original shape.";
        -- the weiner shadow:
            try examining the weiner shadow; [this should never be reached anyway because every action with the shadow gets cut off during Before]
        -- the weiner welcome mat:
            say "The welcome mat is rubbery. And muddy.";
        -- the weiner small wooden table:
            say "Your fingers glide along the smooth wood of the table.";
        -- the weiner-teapot:
            say "The teapot is hard and cool.";
        -- the weiner cloak of darkness:
            say "You feel nothing. You can't even feel your hand.";
        -- the matching weiner boot:
            say "The boot squeezes under your touch, then pops back to its original shape.";
        -- the weiner slip of paper:
            say "The paper crinkles.";
        -- otherwise:
            continue the action. [Important so I don't mess up everybody else's stuff!]
 
Instead of pushing or pulling something fixed in place in a weiner-room when the noun is not the weiner screens and the noun is not the weiner welcome mat and the noun is not the weiner small wooden table: try touching the noun. [making this only for fixed in place stuff in case there's any portable thing that responds, though this misses out the cloak and other stuff]
 
First instead of pulling door4 when the location is MGR1a: try opening door4.
 
[that was a lot of work. Going to try to chill with the other senses]
 
Instead of tasting or eating or drinking something when the location is a weiner-room: say "You decide against putting anything strange in your mouth right now."
 
Instead of listening when the location is MGR1: say "You hear only some faint sounds on the breeze."
 
Instead of listening when the location is MGR1a: say "Everything sounds slightly muffled in the porch."
 
Instead of smelling something in a weiner-room:
    if the noun is:
        -- yourself:
            say "You smell of sweat and mud. If only there were a clawfoot bathtub somewhere.";
        -- MGR1:
            say "The smell of mud and recent rain. (Petrichor, it's called. You learned that word last week.)";
        -- the weiner clogs:
            say "Your shoes smell of mud and your feet.";
        -- the weiner welcome mat:
            say "The odors of rubber and mud blend together into something that makes you question the life choices that led you to this moment. Specifically, the choice to smell a muddy welcome mat.";
        -- MGR1a:
            say "The porch smells of damp wood.";
        -- the weiner-mudroom:
            try smelling MGR1a;
        -- the single weiner boot:
            say "A rich smell of leather. The boot doesn't seem to have been worn recently.";
        -- the matching weiner boot:
            say "A rich smell of leather. The boot doesn't seem to have been worn recently.";
            if the weiner slip of paper is nowhere:
                try searching the matching weiner boot; [it'd probably be better to have a set phrase for searching the boot which I could invoke from a couple of different actions, but I don't want to restructure my code at this point]
        -- pair of weiner slippers:
            say "The slippers smell faintly pungent.";
        -- strange little weiner harvest manikin:
            say "The smell of wet straw.";
        -- the weiner bronze numbers:
            say "A metallic smell.";
        -- the enormous bronze weiner lock plate:
            say "A smell of metal and oil.";
        -- the weiner calfskin coat:
            say "A rich smell of leather.";
        -- the weiner cloak of darkness:
            say "The smell seems to clear your head, like the smell of horseradish without the spice. Just the sensation of vacancy.";
        -- the weiner small wooden table:
            say "A pleasant wooden smell.";
        -- the weiner floor:
            say "A musty damp wooden smell.";
        -- the weiner-teapot:
            say "Metal with a hint of old tea.";
        -- the faint brown mark:
            say "A hint of old tea behind the metal smell.";
        -- the weiner gravel path:
            say "A strong smell of mud and stone.";
        -- the weiner driveway:
            say "In this autumn weather, only a hint of asphalt smell.";
        -- otherwise:
            continue the action.
 
Instead of burning something when the location is MGR1: say "There's no need for light or fire here."
 
Instead of burning something when the location is MGR1a: say "It's a bit dim and chilly in the porch, but you don't need a light or a fire."
 
Chapter 5 - Commentary
 
The commentary of MGR1 is "This is a simple transitional room. For technical reasons, the porch had to be a separate room in order to be able to contain the front door. [paragraph break]The one notable object in the room is the harvest manikin. Manikins like this can be found in Vermont around Halloween, eerie little miniature Wicker Men. The largest concentration of them seems to be in Shelburne, a town that is--well, let's say not exactly full of New England Gothic atmosphere; the most sinister thing about it is that somehow I've never been able to find anything about these manikins on the Internet. The store names were inspired by a little plaza that once contained The Flying Pig (a lovely bookstore), The Bearded Frog, and Jamie Two-Coats. I changed the reference to Stowe because few people have probably heard of Shelburne.[paragraph break]Thanks to YerrikTRB, Petter Sjölund, Andrew Schultz, and Chandler Groover for testing."
 
The commentary of MGR1a is "The mudroom is a common sight in Vermont houses, full of coats, boots, and miscellaneous clutter. Two ancient interactive fiction tropes find a natural home here. The cloak is a tribute to Cloak of Darkness, a short game by Roger Firth that has been implemented in many IF languages as a test case. The keyhole with the key you can push out on the other side goes back at least to Zork II in games, and I believe at least to Enid Blyton's novels before that. In this porch the key is not in the lock, but someone made a game try at doing the trick with the welcome mat before giving up and forgetting their eldritch cloak behind them. [paragraph break]My idea was originally that some crucial information would be written on a piece of paper, to be found in the boot under the cloak. Then the people who were implementing the next puzzle told me that what they needed was a teapot. So I stuck the teapot in plain sight--this isn't at all out of character for a mudroom--and put a silly joke in the boot.[paragraph break]The cluttered porch with luck provides a bit of atmosphere and experiential interactions in between the puzzles. Thanks to YerrikTRB, Petter Sjölund, Andrew Schultz, and Chandler Groover for testing."
 
Chapter 6 - Testing
 
Test walk with "x post/x porch/x manor/x stain/x manikin/x bonnet/take manikin/rub manikin/x skirt/take skirt/take bonnet".
 
Test navigation with "up/down/in/out/north/south/north/exit/north/exit porch/north".
 
Test win with "up/get teapot/down".
 
Test me with "test walk/test navigation/down/test win".
 
[eh, the heck with it]